Unity3D TriPlanar三平面映射 Shader实现

75 阅读 0 评论 50 点赞

我是靠谱客的博主可靠发夹，最近开发中收集的这篇文章主要介绍Unity3D TriPlanar三平面映射 Shader实现，觉得挺不错的，现在分享给大家，希望可以做个参考。

概述

TriPlanar是一种不需要uv的纹理贴图技术，国内好像没有标准的译名，这里暂时称为三平面映射。
那为啥模型会没有uv呢。。这个很简单，有的可能就是单纯模型师忘了做，比如你去网上下模型之类的。不过TriPlanar最重要的用途还是跟程序化生成地形有关，程序化生成地形是比较难对顶点设置uv坐标的。
有的人可能会觉得地形就是一个四边形嘛，从对角线设置[0,0]到[1,1]直接覆盖一张纹理不就好了吗，有一些古老的游戏确实是这么做的，甚至一些现代引擎的地形编辑工具都会默认这么做（比如unity），但是这种作法会在一些例如山峰之类凸起的地方出现很严重的畸变，此时一段纹理会被拉的很长。

如图所示，‘山峰’ 的纹理相比地面纹理明显的被拉长了。unity默认的地形编辑系统就是这种问题。
请添加图片描述
TriPlanar三平面映射的做法就是传入一个三维空间的点和法线，用这个三维空间的点来分别采样三个贴图。

传入参数是三个坐标，分别是三维坐标的xy,yz,xz轴，以及该点在世界空间的法线。我们这里使用世界空间，也可以使用其他空间。

fixed4 color = tex3D(IN.worldPos.xy, IN.worldPos.yz, IN.worldPos.xz, IN.worldNormal);

这个映射函数的实现也比较简单，大致就是根据这三个坐标分别采样三张贴图，然后使用世界发空间的法线的三个分量进行混合。
注意这里使用abs函数保证了法线分量的正值，这主要是因为我们只有三张贴图，因此上下，左右，前后使用的采样贴图是完全一样的，因此只用处理正数就好了，但是如果你想要实现一种’六平面映射’就可以把负值也采样进去。
abs之后还要归一化，我们这里使用的不是normalize，因为我们是要保证三个分量相加等于1，而不是三个分量的平方和等于1

fixed4 tex3D(float2 xy, float2 yz, float2 xz, fixed3 worldNormal)
        {
            fixed4 colorForward = tex2D(_TexForward, yz);
            fixed4 colorUp = tex2D(_TexUp, xz);
            fixed4 colorLeft = tex2D(_TexLeft, xy);

            worldNormal = abs(worldNormal);
            worldNormal = worldNormal / (worldNormal.x + worldNormal.y + worldNormal.z);
            fixed4 finalColor = colorForward * worldNormal.x + colorUp * worldNormal.y + colorLeft * worldNormal.z;
           

            return finalColor;
        }

最后设置三张贴图，效果如下。
请添加图片描述

看上去可能还是有点怪，但主要是我贴图设置的不好。。最主要的就是贴图拉伸的情况已经没有了，在一些45度角的情况下可能还是会有一些，但是也没有那么明显了。

三张贴图也可以设置为同一张贴图。可以看到即使是放大也看不太出那种畸变问题了。
请添加图片描述
参数面板

完整代码

完整代码如下

Shader "LX/triplaneProj"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _TexUp ("TexUp", 2D) = "white" {}
        _TexForward ("TexForward", 2D) = "white" {}
        _TexLeft ("TexLeft", 2D) = "white" {}
        _Glossiness ("Smoothness", Range(0,1)) = 0.5
        _Metallic ("Metallic", Range(0,1)) = 0.0
    }
    SubShader
    {
        Tags
        {
            "RenderType"="Opaque"
        }
        LOD 200

        CGPROGRAM
        #pragma surface surf Standard fullforwardshadows
        #pragma target 3.0

        sampler2D _TexUp;
        sampler2D _TexForward;
        sampler2D _TexLeft;

        struct Input
        {
            float3 worldPos;
            float3 worldNormal;
        };

        half _Glossiness;
        half _Metallic;
        fixed4 _Color;


        fixed4 tex3D(float2 xy, float2 yz, float2 xz, fixed3 worldNormal)
        {
            fixed4 colorForward = tex2D(_TexForward, yz);
            fixed4 colorUp = tex2D(_TexUp, xz);
            fixed4 colorLeft = tex2D(_TexLeft, xy);

            worldNormal = abs(worldNormal);
            worldNormal = worldNormal / (worldNormal.x + worldNormal.y + worldNormal.z);
            fixed4 finalColor = colorForward * worldNormal.x + colorUp * worldNormal.y + colorLeft * worldNormal.z;
            
            return finalColor;
        }


        void surf(Input IN, inout SurfaceOutputStandard o)
        {
            fixed4 color = tex3D(IN.worldPos.xy, IN.worldPos.yz, IN.worldPos.xz, IN.worldNormal);
            o.Albedo = color.rgb;
            o.Metallic = _Metallic;
            o.Smoothness = _Glossiness;
            o.Alpha = color.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}