汇编语言:实验十五 安装新的 int 9 中断例程

实验十五 安装新的 int 9 中断例程

安装一个新的int 9中断例程，功能：在 DOS 下，按下 “A” 键后，除非不再松开，如果松开，就显示满屏幕的”A“,其他的键照常处理。
提示，按下一个键时产生的扫描码称为通码，松开一个键产生的扫描码称为断码。断码 = 通码 + 80h。

求解过程

（1）改变屏幕显示的内容

改变从 B800H 开始的 4000 个字节中的所有偶地址单元中的内容（设置成字符A），当前屏幕显示的内容即发生改变。程序如下：

（2）其他键照常处理

可以调用原 int 9 中断处理程序，来处理其他的键盘输入。

（3）原 int 9 中断例程入口地址的保存

因为在编写新的 int 9 中断例程中要调用原 int 9 中断例程，所以，要保存原 int 9 中断例程的入口地址。保存在哪？显然不能保存在安装程序中，因为安装程序返回后地址将丢失，这里将地址保存在 0:200 单元处。

（4）新 int 9 中断例程的安装

这里只是安装一段程序，在之前的实验中已经做过。可以将 int 9 中断例程安装在 0:204 处。

完整程序

assume cs:code

stack segment
	db 128 dup (0)
stack ends

code segment
start:
	mov ax, stack
	mov ss, ax
	mov sp, 128	;ss指向自定义栈 sp指向栈底
	
	push cs
	pop ds	;ds = cs
	
	mov ax, 0
	mov es, ax;es = 0
	
	mov si, offset int9
	mov di, 204h
	mov cx, offset int9end - offset int9
	cld
	rep movsb ;将int 9程序安装到 0:204h
	
	push es:[9 * 4]
	pop es:[200h]
	push es:[9 * 4 + 2]
	pop es:[202h]	;原int 9中断地址赋值到 200h(IP), 202h(CS)处
	
	cli ;关闭中断
	mov word ptr es:[9 * 4], 204h
	mov word ptr es:[9 * 4 + 2], 0;安装int 9程序
	sti	;打开中断
	
	mov ax, 4c00h
	int 21h
	
int9:
	push ax
	push bx
	push cx
	push es;保存寄存器
	
	in al, 60h;从键盘处读取扫描码
	
	pushf
	call dword ptr cs:[200h]	;调用原 iht 9h 中断
	
	cmp al, 9Eh	;A松开时的扫描码为 9Eh
	jne int9ret	;不相等，结束程序
release:
	mov ax, 0b800h
	mov es, ax
	mov bx, 0
	mov cx, 2000
s:
	mov byte ptr es:[bx], 'A'
	add bx, 2
	loop s

int9ret:
	pop es
	pop cx
	pop bx
	pop ax
	iret

int9end:
	nop

code ends
end start

运行一下：

这里只要稍微加一行代码就可以实现：松开A键后改变屏幕的颜色。

在 s 代码段中添加 ***inc byte ptr es:[bx + 1]***。

再次运行~：

附

参考资料

《汇编语言 第三版》 ---- 王爽

最后

以上就是精明口红为你收集整理的汇编语言:实验十五 安装新的 int 9 中断例程的全部内容，希望文章能够帮你解决汇编语言:实验十五 安装新的 int 9 中断例程所遇到的程序开发问题。

如果觉得靠谱客网站的内容还不错，欢迎将靠谱客网站推荐给程序员好友。