Delphi: 一个用来控制系统音量的类

From: http://dev.21tx.com/2005/05/06/10945.html

一个用来控制系统音量的类，包括了调节左右声道、静音等功能，已被收入CNpack。

// --[Yoyoworks]----------------------------------------------------------------
// 工程名称：prjPowerFlashPlayer
// 软件名称：iPowerFlashPlayer
// 单元作者：许子健
// 开始日期：2004年03月14日，14:31:16
// 单元功能：用于音量调整的类。
// -----------------------------------------------------------[SHANGHAi|CHiNA]--

Unit untTVolume;

Interface

Uses MMSystem, SysUtils;

Type
TVolume = Class(TObject)
Private
FVolume: LongInt; //存储音量。
FIsMute: Boolean; //存储静音值。
Procedure SetLeftVolume(Volume: Integer); //设置左声道的音量。
Function GetLeftVolume: Integer; //获得左声道的音量。
Procedure SetRightVolume(Volume: Integer); //设置右声道的音量。
Function GetRightVolume: Integer; //获得右声道的音量。
Procedure SetIsMute(IsMute: Boolean); //设置是否静音。
Public
Constructor Create;
Destructor Destroy; Override;
Published
Property LeftVolume: Integer Read GetLeftVolume Write SetLeftVolume;
Property RightVolume: Integer Read GetRightVolume Write SetRightVolume;
Property Mute: Boolean Read FIsMute Write SetIsMute;
End;

Implementation

// -----------------------------------------------------------------------------
// 过程名： TVolume.Create
// 参数： 无
// 返回值： 无
// -----------------------------------------------------------------------------
Constructor TVolume.Create;
Begin
Inherited Create;
FVolume := 0;
FIsMute := False;
//初始化变量
waveOutGetVolume(0, @FVolume); //得到现在音量
End;

// -----------------------------------------------------------------------------
// 过程名： TVolume.Destroy
// 参数： 无
// 返回值： 无
// -----------------------------------------------------------------------------
Destructor TVolume.Destroy;
Begin
Inherited Destroy;
End;

// -----------------------------------------------------------------------------
// 过程名： TVolume.SetLeftVolume
// 参数： Volume: Integer
// 返回值： 无
// -----------------------------------------------------------------------------
Procedure TVolume.SetLeftVolume(Volume: Integer);
Begin
If (Volume < 0) Or (Volume > 255) Then
Raise Exception.Create('Range error of the left channel [0 to 255].');
//如果“Volume”参数不在0至255的范围里，则抛出异常。

If FIsMute = False Then
Begin
waveOutGetVolume(0, @FVolume);
//@示指向变量Volume的指针（32位），调用此函数的用意就是得到右声道的值，做到在调节左声道的时候，不改变右声道。
FVolume := FVolume And $FFFF0000 Or (Volume Shl 8); //数字前加$表示是十六进制
waveOutSetVolume(0, FVolume);
End
//如果不是静音状态，则改变音量；
Else
FVolume := FVolume And $FFFF0000 Or (Volume Shl 8);
//否则，只改变变量。

End;

// -----------------------------------------------------------------------------
// 过程名： TVolume.SetRightVolume
// 参数： Volume: Integer
// 返回值： 无
// -----------------------------------------------------------------------------
Procedure TVolume.SetRightVolume(Volume: Integer);
Begin
If (Volume < 0) Or (Volume > 255) Then
Raise Exception.Create('Range error of the right channel [0 to 255].');

If FIsMute = False Then
Begin
waveOutGetVolume(0, @FVolume);
FVolume := FVolume And $0000FFFF Or (Volume Shl 24);
waveOutSetVolume(0, FVolume);
End
Else
FVolume := FVolume And $0000FFFF Or (Volume Shl 24);
End;

// -----------------------------------------------------------------------------
// 过程名： TVolume.SetIsMute
// 参数： IsMute: Boolean
// 返回值： 无
// -----------------------------------------------------------------------------
Procedure TVolume.SetIsMute(IsMute: Boolean);
Begin
FIsMute := IsMute;
If FIsMute = True Then
waveOutSetVolume(0, 0)
Else
waveOutSetVolume(0, FVolume)
End;

// -----------------------------------------------------------------------------
// 函数名： TVolume.GetLeftVolume
// 参数： 无
// 返回值： Integer
// -----------------------------------------------------------------------------
Function TVolume.GetLeftVolume: Integer;
Begin
If FIsMute = False Then
waveOutGetVolume(0, @FVolume); //得到现在音量
Result := Hi(FVolume); //转换成数字

End;

// -----------------------------------------------------------------------------
// 函数名： TVolume.GetRightVolume
// 参数： 无
// 返回值： Integer
// -----------------------------------------------------------------------------
Function TVolume.GetRightVolume: Integer;
Begin
If FIsMute = False Then
waveOutGetVolume(0, @FVolume); //得到现在音量
Result := Hi(FVolume Shr 16); //转换成数字
End;

End.

最后

以上就是丰富曲奇为你收集整理的Delphi: 一个用来控制系统音量的类的全部内容，希望文章能够帮你解决Delphi: 一个用来控制系统音量的类所遇到的程序开发问题。

如果觉得靠谱客网站的内容还不错，欢迎将靠谱客网站推荐给程序员好友。