8086汇编实现1到1000的累加和

         ;实现1-1000的累加和
         ;文件说明：硬盘主引导扇区代码
         ;创建日期：2013-5-4 21：31

         jmp near start

 message db '1+2+3+...+1000='

 start:
         mov ax,0x7c0           ;设置数据段的段基地址
         mov ds,ax

         mov ax,0xb800          ;设置附加段基址到显示缓冲区
         mov es,ax

         ;以下显示字符串
         mov si,message
         mov di,0
         mov cx,start-message
     @g:
         mov al,[si]
         mov [es:di],al
         inc di
         mov byte [es:di],0x07
         inc di
         inc si
         loop @g

         ;以下计算1到100的和
         xor ax,ax
         xor dx,dx
         mov cx,1000
     @f:
         add ax,cx
         adc dx,0
         loop @f

         ;以下计算累加和的每个数位
         xor cx,cx              ;设置堆栈段的段基地址
         mov ss,cx
         mov sp,cx

         mov bx,10
         xor cx,cx
         inc cx
         div bx
         or dl,0x30
         push dx
     @d:
         inc cx
         xor dx,dx
         div bx
         or dl,0x30
         push dx
         cmp ax,0
         jne @d

         ;以下显示各个数位
     @a:
         pop dx
         mov [es:di],dl
         inc di
         mov byte [es:di],0x07
         inc di
         loop @a

         jmp near $


times 510-($-$$) db 0
                 db 0x55,0xaa

再来张效果图。。。运行在virtual box

最后

以上就是感动嚓茶为你收集整理的8086汇编实现1到1000的累加和的全部内容，希望文章能够帮你解决8086汇编实现1到1000的累加和所遇到的程序开发问题。

如果觉得靠谱客网站的内容还不错，欢迎将靠谱客网站推荐给程序员好友。