易语言查找指定颜色并将鼠标移动到指定坐标的代码

131 阅读 0 评论 87 点赞

我是靠谱客的博主背后短靴，最近开发中收集的这篇文章主要介绍易语言查找指定颜色并将鼠标移动到指定坐标的代码，觉得挺不错的，现在分享给大家，希望可以做个参考。

概述

DLL命令表

.版本 2
.DLL命令 移动鼠标, , "user32", "SetCursorPos"
 .参数 x, 整数型
 .参数 y, 整数型

查找指定颜色例程

.版本 2
.程序集 窗口程序集1
.子程序 _查找按钮_被单击, , , 查找颜色
.局部变量 临时字节集, 字节集
.局部变量 颜色, 字节集
.局部变量 找到位置, 整数型
.局部变量 x, 整数型
.局部变量 y, 整数型
.局部变量 宽, 整数型
.局部变量 高, 整数型
临时字节集 ＝ 快照 (, , ) ' 取屏幕
宽 ＝ 临时字节集 [19] ＋ 临时字节集 [20] × 256
高 ＝ 临时字节集 [23] ＋ 临时字节集 [24] × 256
临时字节集 ＝ 取字节集右边 (临时字节集, 取字节集长度 (临时字节集) － 54)
颜色 ＝ { 0, 0, 0 }
颜色 [1] ＝ 到字节 (到数值 (编辑框B.内容))
颜色 [2] ＝ 到字节 (到数值 (编辑框G.内容))
颜色 [3] ＝ 到字节 (到数值 (编辑框R.内容))
找到位置 ＝ -1
.循环判断首 ()
 找到位置 ＝ 寻找字节集 (临时字节集, 颜色, 找到位置 ＋ 1)
 .如果真 (找到位置 ＝ -1)
  跳出循环 ()
 .如果真结束
.循环判断尾 ((找到位置 － 1) ％ 3 ≠ 0)
.如果 (找到位置 ≠ -1)
 x ＝ ((找到位置 － 1) ÷ 3 ＋ 1) ％ 宽
 y ＝ 高 － ((找到位置 － 1) ÷ 3 ＋ 1) ＼ 宽
 编辑框结果.内容 ＝ “X：” ＋ 到文本 (x) ＋ “ Y：” ＋ 到文本 (y)
 .如果真 (选择框1.选中 ＝ 真)
  移动鼠标 (x, y)
 .如果真结束
.否则
 编辑框结果.内容 ＝ “没有找到”
.如果结束
.子程序 _编辑框颜色值_内容被改变
.局部变量 字节集, 字节集
.局部变量 R, 整数型
.局部变量 G, 整数型
.局部变量 B, 整数型
字节集 ＝ 到字节集 (到整数 (编辑框颜色值.内容))
R ＝ 字节集 [1]
G ＝ 字节集 [2]
B ＝ 字节集 [3]
编辑框R.内容 ＝ 到文本 (R)
编辑框G.内容 ＝ 到文本 (G)
编辑框B.内容 ＝ 到文本 (B)
颜色画板.画板背景色 ＝ 到整数 (编辑框颜色值.内容)
.子程序 __启动窗口_创建完毕
_编辑框颜色值_内容被改变 ()

运行结果：