易语言实现快捷登录查询Q币消费记录的代码

145 阅读 0 评论 96 点赞

我是靠谱客的博主活泼手链，最近开发中收集的这篇文章主要介绍易语言实现快捷登录查询Q币消费记录的代码，觉得挺不错的，现在分享给大家，希望可以做个参考。

概述

常量数据表

.版本 2
.常量 常量1, "<文本长度: 139>", , "accttype": "(.*?)"[sS]*?"balance": "(.*?)"[sS]*?"info": "(.*?)"[sS]*?"pay": "(.*?)"[sS]*?"save": "(.*?)"[sS]*?"tranday": "(.*?)"
.常量 常量2, "<文本长度: 15>", , "list": [ ] } }

全局变量表

.版本 2
.全局变量 Cookie, 文本型
.全局变量 G_tk, 文本型
.全局变量 QQ号码, 文本型

QQ快捷登陆的代码

.版本 2
.支持库 HtmlView
.程序集 窗口程序集_启动窗口
.子程序 _超文本浏览框1_跳转完毕
.如果真 (超文本浏览框1.地址 ＝ “https://my.pay.qq.com/account/account_qdqb_trade_record.shtml”)
  Cookie ＝ 网页_取Cookie (“qq.com”)
  G_tk ＝ 计算G_tk (文本_取出中间文本 (Cookie, “skey=”, “;”))
  QQ号码 ＝ 文本_取出中间文本 (Cookie, “uin=o”, “;”)
  载入 (窗口1, , 假)
  销毁 ()
.如果真结束
.子程序 计算G_tk, 文本型
.参数 skey, 文本型
.局部变量 hash, 整数型
.局部变量 计次, 整数型
hash ＝ 5381
.变量循环首 (1, 取文本长度 (skey), 1, 计次)
  hash ＝ hash ＋ hash × 求次方 (2, 5) ＋ 取字节集数据 (编码_Ansi到Unicode (取文本中间 (skey, 计次, 1)), 3, )
.变量循环尾 ()
返回 (到文本 (位与 (hash, 进制_十六到十 (“7fffffff”))))
.子程序 __启动窗口_创建完毕

Q币消费查询的代码

此功能需要加载精易模块5.6

.版本 2
.支持库 EThread
.支持库 spec
.支持库 iext
.程序集 窗口程序集_窗口1
.子程序 _窗口1_创建完毕
截止编辑框.内容 ＝ 到文本 (取年份 (取现行时间 ())) ＋ “-” ＋ 到文本 (取月份 (取现行时间 ())) ＋ “-” ＋ 到文本 (取日 (取现行时间 ()))
窗口1.标题 ＝ 窗口1.标题 ＋ “ [” ＋ QQ号码 ＋ “]”
.子程序 _查询按钮_被单击
.判断开始 (查询按钮.标题 ＝ “开始查询”)
  导出按钮.禁止 ＝ 假
  查询按钮.禁止 ＝ 真
  启动线程 (&子程序_开始查询, , )
.默认
  查询按钮.标题 ＝ “开始查询”
.判断结束
.子程序 子程序_开始查询
.局部变量 返回文本, 文本型
.局部变量 共记录, 文本型
.局部变量 正则, 正则表达式类
.局部变量 i, 整数型
.局部变量 M, 整数型
.局部变量 页数, 整数型, 静态
返回文本 ＝ 网页_访问S (“http://my.pay.qq.com/cgi-bin/personal/account_tradeinfo.cgi?coin_type=0&start_date=” ＋ 起始编辑框.内容 ＋ “&end_date=” ＋ 截止编辑框.内容 ＋ “&page_no=1&channel=qdqb&per=10&extcode=&t=” ＋ 时间_取随机时间戳 (), , , Cookie)
调试输出 (返回文本)
共记录 ＝ 文本_取出中间文本 (返回文本, #引号 ＋ “count” ＋ #引号 ＋ “: ” ＋ #引号, #引号)
查询按钮.标题 ＝ “停止查询[1/” ＋ 共记录 ＋ “]”
页数 ＝ 0
超级列表框.全部删除 ()
线程_初始化COM库 ()
.判断循环首 (共记录 ≠ “”)
  页数 ＝ 页数 ＋ 1
  返回文本 ＝ 网页_访问S (“http://my.pay.qq.com/cgi-bin/personal/account_tradeinfo.cgi?coin_type=0&start_date=” ＋ 起始编辑框.内容 ＋ “&end_date=” ＋ 截止编辑框.内容 ＋ “&page_no=” ＋ 到文本 (页数) ＋ “&channel=qdqb&per=10&extcode=&t=” ＋ 时间_取随机时间戳 (), , , Cookie)
  返回文本 ＝ 编码_usc2到ansi (返回文本)
  调试输出 (返回文本)
  正则.创建 (#常量1, 返回文本)
  .计次循环首 (正则.取匹配数量 (), i)
    M ＝ 超级列表框.插入表项 (, , , , , )
    超级列表框.置标题 (M, 0, 正则.取子匹配文本 (i, 6))
    超级列表框.置标题 (M, 1, 子程序_处理类型 (正则.取子匹配文本 (i, 1)))
    超级列表框.置标题 (M, 2, 子程序_处理收入 (正则.取子匹配文本 (i, 5)))
    超级列表框.置标题 (M, 3, 子程序_处理收入 (正则.取子匹配文本 (i, 4)))
    超级列表框.置标题 (M, 4, 正则.取子匹配文本 (i, 2))
    超级列表框.置标题 (M, 5, 正则.取子匹配文本 (i, 3))
    查询按钮.标题 ＝ “停止查询[” ＋ 到文本 (超级列表框.取表项数 ()) ＋ “/” ＋ 共记录 ＋ “]”
  .计次循环尾 ()
  .如果真 (寻找文本 (返回文本, #常量2, , 假) ≠ -1)
    跳出循环 ()
  .如果真结束
  .如果真 (查询按钮.标题 ＝ “开始查询”)
    跳出循环 ()
  .如果真结束
  程序_延时 (50)
.判断循环尾 ()
查询按钮.标题 ＝ “开始查询”
线程_取消COM库 ()
查询按钮.禁止 ＝ 假
信息框 (“日期:” ＋ 起始编辑框.内容 ＋ “ - ” ＋ 截止编辑框.内容 ＋ #换行符 ＋ #换行符 ＋ “共消费了：” ＋ 子程序_计算消费 () ＋ “ Q币”, 0, “消费结果：”, _启动窗口)
.子程序 子程序_计算消费, 文本型
.局部变量 i, 整数型
.局部变量 消费, 文本型
.局部变量 Q币, 文本型
.局部变量 总数, 文本型
.计次循环首 (超级列表框.取表项数 (), i)
  消费 ＝ 超级列表框.取标题 (i － 1, 3)
  Q币 ＝ 超级列表框.取标题 (i － 1, 1)
  .如果真 (Q币 ＝ “Q币” 或 Q币 ＝ “Q点”)
    .如果真 (Q币 ＝ “Q点”)
      消费 ＝ 到文本 (到数值 (消费) ÷ 10)
    .如果真结束
    总数 ＝ 到文本 (到数值 (总数) ＋ 到数值 (消费))
  .如果真结束
.计次循环尾 ()
返回 (总数)
.子程序 子程序_处理类型, 文本型
.参数 accttype, 文本型
.如果真 (accttype ＝ “1”)
  返回 (“Q币”)
.如果真结束
.如果真 (accttype ＝ “3”)
  返回 (“Q点”)
.如果真结束
返回 (accttype)
.子程序 子程序_处理收入, 文本型
.参数 收入, 文本型
.如果真 (收入 ＝ “”)
  返回 (“—”)
.如果真结束
返回 (收入)
.子程序 _导出按钮_被单击
.局部变量 i, 整数型
.局部变量 导出的内容, 文本型
.计次循环首 (超级列表框.取表项数 (), i)
  导出的内容 ＝ 导出的内容 ＋ 超级列表框.取标题 (i － 1, 0) ＋ “--” ＋ 超级列表框.取标题 (i － 1, 1) ＋ “--” ＋ 超级列表框.取标题 (i － 1, 2) ＋ “--” ＋ 超级列表框.取标题 (i － 1, 3) ＋ “--” ＋ 超级列表框.取标题 (i － 1, 5) ＋ “--” ＋ 超级列表框.取标题 (i － 1, 6) ＋ #换行符
  处理事件 ()
.计次循环尾 ()
.如果 (写到文件 (取运行目录 () ＋ “[” ＋ QQ号码 ＋ “]Q币消费查询.txt”, 到字节集 (导出的内容)))
  信息框 (“导出成功”, 0, , )
.否则
  信息框 (“导出失败”, 0, , )
.如果结束

运行结果：