易语言注册机生成永久或限时注册码的写法

231 阅读 0 评论 153 点赞

我是靠谱客的博主灵巧睫毛膏，最近开发中收集的这篇文章主要介绍易语言注册机生成永久或限时注册码的写法，觉得挺不错的，现在分享给大家，希望可以做个参考。

概述

DLL命令表

.版本 2
.DLL命令 CryptCreateHash, 整数型, "advapi32.dll", "CryptCreateHash", 公开
  .参数 hProv, 整数型
  .参数 Algid, 整数型
  .参数 hKey, 整数型
  .参数 dwFlags, 整数型
  .参数 phHash, 整数型, 传址
.DLL命令 CryptDestroyHash, 整数型, "advapi32.dll", "CryptDestroyHash", 公开
  .参数 hHash, 整数型, 传址
.DLL命令 CryptGetHashParam, 整数型, "advapi32.dll", "CryptGetHashParam", 公开
  .参数 hHash, 整数型
  .参数 dwParam, 整数型
  .参数 pByte, 字节集
  .参数 pdwDataLen, 整数型, 传址
  .参数 dwFlags, 整数型
.DLL命令 CryptReleaseContext, 整数型, "advapi32.dll", "CryptReleaseContext", 公开
  .参数 hProv, 整数型, 传址
  .参数 dwFlags, 整数型, 传址
.DLL命令 CryptHashData, 整数型, "advapi32.dll", "CryptHashData", 公开
  .参数 hHash, 整数型
  .参数 pbData, 字节集, 传址
  .参数 dwDataLen, 整数型
  .参数 dwFlags, 整数型
.DLL命令 CryptAcquireContextA, 整数型, "advapi32.dll", "CryptAcquireContextA", 公开
  .参数 phProv, 整数型, 传址
  .参数 pszContainer, 文本型
  .参数 pszProvider, 文本型
  .参数 dwProvType, 整数型
  .参数 dwFlags, 整数型

生成注册码的代码

.版本 2
.支持库 dp1
.程序集 窗口程序集1
.子程序 _生成按钮_被单击
.局部变量 sj1, 文本型
.局部变量 sj2, 文本型
.局部变量 sj3, 文本型
.局部变量 临时文本, 文本型
.局部变量 临时时间, 日期时间型
.如果 (类型组合框.现行选中项 ＝ 0)
  临时时间 ＝ [2080年12月31日]
.否则
  临时时间 ＝ 日期框.今天
.如果结束
sj1 ＝ 到文本 (取年份 (临时时间))
sj2 ＝ 到文本 (取月份 (临时时间))
sj2 ＝ 选择 (取文本长度 (sj2) ＝ 1, “0” ＋ sj2, sj2)
sj3 ＝ 到文本 (取日 (临时时间))
sj3 ＝ 选择 (取文本长度 (sj3) ＝ 1, “0” ＋ sj3, sj3)
临时文本 ＝ 到文本 (左移 (到数值 (sj1 ＋ sj2 ＋ sj3), 4))
临时文本 ＝ 进制_十到十六 (到数值 (临时文本))
临时文本 ＝ 临时文本 ＋ 进制_十到十六 (取文本长度 (临时文本) ＋ 1)
临时文本 ＝ 到大写 (取数据摘要 (到字节集 (机器码编辑框.内容 ＋ 校验_取sha1 (到字节集 (机器码编辑框.内容))))) ＋ 临时文本
注册码编辑框.内容 ＝ 临时文本
置剪辑板文本 (注册码编辑框.内容)
.子程序 _类型组合框_列表项被选择
.如果 (类型组合框.现行选中项 ＝ 0)
  日期框.禁止 ＝ 真
.否则
  日期框.禁止 ＝ 假
.如果结束
.子程序 进制_十到十六, 文本型, 公开, 运算_十进制到十六进制
.参数 十进制数, 整数型
返回 (取十六进制文本 (十进制数))
.子程序 校验_取sha1, 文本型, 公开, 返回40位的校验数据
.参数 字节集数据, 字节集, , 要取数据摘要的字节集
返回 (到小写 (MD过程 (字节集数据, 32772, 20)))
.子程序 MD过程, 文本型
.参数 x, 字节集
.参数 种类, 整数型
.参数 长度, 整数型
.局部变量 hCryptProv, 整数型
.局部变量 hKey, 整数型
.局部变量 hHash, 整数型
.局部变量 pbBuffer, 字节集
.局部变量 cbHash, 整数型
.局部变量 rgbHash, 字节集
.局部变量 rgbDigits, 字节集
.局部变量 局_MD5, 字节集
.局部变量 b, 整数型
.局部变量 i, 整数型
.局部变量 len, 整数型
.如果 (CryptAcquireContextA (hCryptProv, “”, “”, 1, -268435456) ＝ 0)
  .如果真 (CryptAcquireContextA (hCryptProv, “”, “”, 1, 0) ＝ 0)
    返回 (“”)
  .如果真结束
.否则
  .如果 (CryptCreateHash (hCryptProv, 种类, hKey, 0, hHash) ＝ 0)
    CryptReleaseContext (hCryptProv, 0)
    返回 (“”)
  .否则
    pbBuffer ＝ x
    len ＝ 取字节集长度 (x)
    .如果 (CryptHashData (hHash, pbBuffer, len, 0) ＝ 0)
      CryptDestroyHash (hHash)
      CryptReleaseContext (hCryptProv, 0)
      返回 (“”)
    .否则
      rgbHash ＝ 取空白字节集 (长度)
      cbHash ＝ 长度
      .如果 (CryptGetHashParam (hHash, 2, rgbHash, cbHash, 0) ＝ 0)
        CryptDestroyHash (hHash)
        CryptReleaseContext (hCryptProv, 0)
        返回 (“”)
      .否则
        rgbDigits ＝ 到字节集 (“0123456789ABCDEF”)
        局_MD5 ＝ 取空白字节集 (长度 × 2)
        .变量循环首 (0, cbHash － 1, 1, i)
          b ＝ rgbHash [i ＋ 1]
          局_MD5 [i × 2 ＋ 1] ＝ rgbDigits [右移 (b, 4) ＋ 1]
          局_MD5 [i × 2 ＋ 2] ＝ rgbDigits [位与 (b, 15) ＋ 1]
        .变量循环尾 ()
        CryptDestroyHash (hHash)
        CryptReleaseContext (hCryptProv, 0)
      .如果结束
    .如果结束
  .如果结束
.如果结束
返回 (到文本 (局_MD5))

运行结果：