汇编语言实验15（王爽第三版）安装新的int 9中断例程

93 阅读 0 评论 62 点赞

我是靠谱客的博主粗心路人，这篇文章主要介绍汇编语言实验15（王爽第三版）安装新的int 9中断例程，现在分享给大家，希望可以做个参考。

实验15：安装新的int 9中断例程
功能：
在DOS下，按下“A”键后，除非不再松开，如果松开，就显示满屏幕的“A”，其他的按键照常处理。
提示：
“A”的通码为1EH，断码为9EH。
代码如下：

复制代码

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
assume cs:code
stack segment
db 128 dup(0)
stack ends
code segment
start:	mov ax,stack
mov ss,ax
mov sp,128
push cs
pop ds
mov ax,0
mov es,ax
mov si,offset int9
mov di,204h
mov cx,offset int9end-offset int9
cld
rep movsb
push es:[9*4]
pop es:[200h]
push es:[9*4+2]
pop es:[202h]
cli
mov word ptr es:[9*4],204h
mov word ptr es:[9*4+2],0
sti
mov ax,4c00h
int 21h
;以下为新的int 9中断例程。。。。。。。。。。。。。。。
int9:	push ax
push bx
push cx
push es
in al,60h
;读键盘输入
pushf
;标志寄存器入栈
call dword ptr cs:[200h]
;调用原int 9
cmp al,9Eh
;是否松开'a'键
jne int9ret
mov ax,0b800h
mov es,ax
mov bx,0
mov cx,2000
s:	mov byte ptr es:[bx],'A'
add bx,2
loop s
;全屏显示'A'
int9ret:pop es
pop cx
pop bx
pop ax
iret
int9end:nop
code ends
end start